邮件服务器-邮件系统-邮件技术论坛(BBS)

标题: [分享]Exchange 2003是禁用 M: 驱动器映射功能，如何Exchange 2000禁用M: 驱动器 [打印本页]

作者: 钉子 时间: 2003-9-26 08:33
标题: Re:IMAIL与EXCHANGE2K相比较，IMAIL的防垃圾邮件的功能要好很多
1.感觉两者的适用性不同，EX适用内部信息平台。Imail用于专业邮件服务。 
2.总的开发时间也不同，Imail用了十年的时间来完美。 
3.还有EX2003有和Imail一样的利用公布列表的功能。 
我认为，用于公司内部EX还是好过Imail，但是如果你用来做邮件服务，Imail是首选。

作者: pangbo001 时间: 2003-9-29 21:02
标题: Re:IMAIL与EXCHANGE2K相比较，IMAIL的防垃圾邮件的功能要好很多
现在的公司一般都需要内部信息平台和外部MAIL服务器，那该怎样选择呢？ 
都安装吗？ 
我在同一台机子上安装EX与MD或WEBEASYMAIL或其他，都出现不正常情况。 
要么是收不到信，要么是发不了信。好烦！！！

作者: 钉子 时间: 2003-9-30 08:07
标题: Re:IMAIL与EXCHANGE2K相比较，IMAIL的防垃圾邮件的功能要好很多
1.同一台机当然是不能安装多个系统呀。 
2.内外部主要是看你的用户和需求，

作者: 钉子 时间: 2003-10-20 13:56
标题: [分享]Exchange 2003是禁用 M: 驱动器映射功能，如何Exchange 2000禁用M: 驱动器
今天在看<<Exchange Server 2003 新增功能>>看到这个问题,给大家分享一下,希望对有这个需求的同好参考: 
1.为什么要禁用M? 
在某些情况下，邮箱存储会由于文件系统操作（例如，在 M: 驱动器上运行文件级别的病毒扫描程序，或在该驱动器上运行文件备份软件）而被破坏。 
 
2.如何禁用? 
对于 Exchange 2000，应考虑禁用 M: 驱动器映射功能。有关如何禁用此项功能的信息，请参阅 Microsoft 知识库文章 305145“HOW TO: Remove the IFS Mapping for Drive M in Exchange 2000 Server”(<a target=_blank href=http://support.microsoft.com/?kbid=305145)>http://support.microsoft.com/?kbid=305145)</a>（英文）.具体内容如下: 
概要 
本分步指南介绍如何从驱动器 M 删除 Exchange 2000 可安装文件系统 (IFS) 映射。 
 
IFS 提供了通过 Win32 文件系统 API 来访问 Exchange 2000 信息存储区这一访问方式。 Exchange 2000 IFS 支持 \\.\backofficestorage\ 命名空间。为兼容和方便起见，Exchange 2000 也支持正常的驱动器命名空间，默认情况下是驱动器 M:\。 IFS 是作为通过标准文件系统接口访问 Exchange 2000 信息存储区的一种方法被引入 Exchange 2000 的。 
 
不过，在某些情况下，使用 IFS 时可能会遇到一些问题。正是因为这些问题，所以 Microsoft 建议您删除到驱动器 M 的 IFS 映射，除非您有明确的原因不需要使用 IFS。即使删除了驱动器 M 或其他驱动器盘符映射，\\.\backofficestorage\ 命名空间仍保持可用。 
 
保留 IFS 映射的理由包括： 
将“Microsoft FrontPage 扩展”用于“Web 存储系统窗体”。 
需要使用驱动器 M 映射进行开发。 
使用 Microsoft Internet Explorer 将驱动器 M 作为一个文件系统来搜索。 
如果上面所列任意一条理由与您的 Exchange 2000 环境相符，那么 Microsoft 建议您在存在这些情况的服务器上保留此映射。 
 
如要删除驱动器 M 映射，请使用本文中提供的脚本。 
 
返回页首 
创建驱动器 M 删除脚本 
若要创建驱动器 M 删除脚本，请按照下列步骤操作： 
启动一个文本编辑器（如 Microsoft 记事本），然后将下面的脚本复制并粘贴到编辑器中： 
@setlocal 
@if "%1"=="" goto usage 
@if "%1"=="/?" goto usage 
@if "%1"=="-?" goto usage 
@rem Parameter is either a drive letter, or "none" 
 
@rem check for presence of adsutil.vbs 
@set adu=%systemdrive%\inetpub\adminscripts\adsutil.vbs 
@if exist %adu% goto stopsrv 
@echo This tool requires %adu% from the IIS scripts. 
@goto fail 
 
:stopsrv 
@rem Record what Exchange services are currently running 
@echo off 
@set StartSA=0 
@set StartIS=0 
@set StartMTA=0 
@set StartWWW=0 
For /f "delims=" %%a in ('net start') do if "%%a" == " Microsoft Exchange System Attendant" set StartSA=1 
For /f "delims=" %%a in ('net start') do if "%%a" == " Microsoft Exchange Information Store" set StartIS=1 
For /f "delims=" %%a in ('net start') do if "%%a" == " Microsoft Exchange MTA Stacks" set StartMTA=1 
For /f "delims=" %%a in ('net start') do if "%%a" == " World Wide Web Publishing Service" set StartWWW=1 
@echo on 
@echo Stopping Exchange services... 
net stop msexchangesa /y 
 
@echo Stopping Web services... 
net stop w3svc /y 
 
@if "%temp%" == "" set temp="C:\" 
@set regfile=%temp%\addm.reg 
@echo REGEDIT4 > "%regfile%" 
@if "%1"=="none" goto deldrive 
@set drive=%1 
@set newdrive=%drive:~0,1% 
@echo Adding %newdrive% drive mapping to the registry... 
@echo [HKEY_LOCAL_MACHINE\System\CurrentControlSet\Services\EXIFS\Parameters] >> "%regfile%" 
@echo "DriveLetter"="%newdrive%" >> "%regfile%" 
@goto doregedit 
:deldrive 
@echo removing existing drive letter mapping... 
For /f "delims=\=>; tokens=1,2*" %%a in ('subst') do ( if /i "%%c" == " BackOfficeStorage" ( subst %%a /d ) 
) 
@echo Removing drive mapping from the registry... 
@echo [HKEY_LOCAL_MACHINE\System\CurrentControlSet\Services\EXIFS\Parameters] >> "%regfile%" 
@echo "DriveLetter"="" >> "%regfile%" 
:doregedit 
@type %regfile% 
regedit -s "%regfile%" 
@if errorlevel 0 goto mb 
@goto fail 
 
:mb 
@echo Touching the metabase to force update of Exchange virtual roots... 
cscript %adu% delete /ds2mb/HighWaterMarks 
@goto restart 
 
:restart 
@echo Restarting services... 
@if %StartSA%==1 net start "Microsoft Exchange System Attendant" /y 
@if %StartIS%==1 net start "Microsoft Exchange Information Store" /y 
@if %StartMTA%==1 net start "Microsoft Exchange MTA Stacks" /y 
@if %StartWWW%==1 net start w3svc /y 
@goto done 
 
:fail 
@echo The operation did not succeed. 
@goto end 
 
:done 
@echo Done. 
@goto end 
 
:usage 
@echo Usage: ifsdrive ^<drive-letter^> 
@echo ifsdrive none 
@echo Modifies or removes the mapping of Exchange storage to a local drive letter. 
@echo Specify a single letter to map Exchange storage to that drive. 
@echo Specify "none" (without quotes) to remove the mapping. 
@goto end 
 
:end 
@if not "%regfile%" == "" del "%regfile%" 
用 Ifsdrive.cmd 这一文件名保存此文本文件。 
返回页首 
运行驱动器 M 删除脚本 
创建驱动器 M 删除脚本后，您需要从 Exchange 2000 服务器上使用命令来运行此脚本： 
打开一个命令窗口，然后将目录改到保存此脚本的文件夹。 
在命令提示符下，键入下面的命令以删除驱动器 M 映射： 
ifsdrive none 
 
备注：为删除该映射，请使用完整的“none”一词。 
在脚本运行时，它下一步要执行的操作将显示出来。脚本完成时，最后一行将显示“Done”（完成）。 
 
备注：此脚本先停止然后又启动 Exchange 2000 消息传输代理 (MTA)、Exchange 2000 Post Office Protocol 第 3 版 (POP3)、Exchange 2000 Internet Message Access Protocol、Version 4rev1 (IMAP4)、“Exchange 2000 信息存储区”，以及“万维网发布服务”。 
如果误删了驱动器 M 映射，而现在因为前面所列原因之一又需要用它，可以在提示符下键入下面的命令（其中驱动器盘符是 IFS 驱动器映射的盘符）： 
ifsdrive 驱动器盘符 
 
驱动器盘符默认情况下是驱动器 M，但如果 IFS 驱动器映射曾被改为另一个驱动器盘符，那么请改用新的驱动器盘符。 
删除 IFS 驱动器映射后，在 Exchange 2000 信息存储区服务启动时，下面这一错误消息将记入应用程序事件日志： 
 
来源： ExWin32 
EventID：1 
类型：错误 
描述： 
Exchange IFS 未能映射驱动器： ?:。请释放驱动器 ?: 以便使用 Exchange IFS。 
您可以放心地忽略此错误信息；以后的 Exchange 2000 版本中将删除此消息。 
 
返回页首 
参考 
有关其他与保留驱动器 M 映射相关的一些问题的信息，请单击下面的文章编号以查看 Microsoft 知识库中的文章： 
271465 XADM： Clients Cannot Access Attachments After You Back Up Drive M（备份驱动器 M 后客户机不能访问附件） 
 
281673 PRB： Moving Items Within Drive M of Exchange Can Remove Item Properties（在 Exchange 的驱动器 M 中移动项目会删除项目属性） 
 
298924 XADM： Do Not Back Up or Scan Exchange 2000 Drive M（不要备份或扫描 Exchange 2000 驱动器 M） 
 
299046 XADM： Calendar Items Disappear from User's Folders（日历项目从用户的文件夹中消失） 
 
303245 XCLN： Item Count Incorrect for Messages with Modified Permission（修改权限后，消息的项目计数错误） 
 
有关与驱动器 M 的防病毒扫描相关的一些问题（与保留驱动器 M 映射有关联）的其他信息，请单击下面的文章编号以查看 Microsoft 知识库中的文章： 
245822 XGEN： Recommendations for Troubleshooting an Exchange Server Computer with Antivirus Installed（针对安装了防病毒软件的 Exchange Server 计算机的故障排除建议） 
 
298551 XADM： Large Number of Transaction Logs Created（创建了大量事务日志）

作者: summer2678 时间: 2003-12-18 09:18
标题: Re:[分享]Exchange 2000是禁用 M: 驱动器映射功能
看不懂，大哥

作者: mis 时间: 2003-12-24 10:56
标题: Re:[分享]Exchange 2000是禁用 M: 驱动器映射功能
e文太差﹐看不懂ing

作者: fong 时间: 2003-12-24 15:21
标题: Re:[分享]Exchange 2000是禁用 M: 驱动器映射功能
是哦，可以不可以translate 一下啊！

作者: 钉子 时间: 2003-12-30 21:17
标题: Re:[分享]Exchange 2000是禁用 M: 驱动器映射功能
终于是中文的了。。

作者: xuzech 时间: 2004-7-8 08:42
标题: Re:[分享]Exchange 2000是禁用 M: 驱动器映射功能
謝謝提供分享。

作者: wollate 时间: 2004-7-8 09:01
标题: Re:[分享]Exchange 2000是禁用 M: 驱动器映射功能
收藏，赫赫。

欢迎光临邮件服务器-邮件系统-邮件技术论坛(BBS) (http://bbs.5dmail.cn/)